############################################
#
# Seestar Mosaic in HOO v 1.2
# December 2024
# (C) Maciej Obarzanek
#
############### SCRIPT INFO ################
#
# Script for Seestar S50 that extracts 
# Ha and OIII and combine HOO mosaic of them
#
# Needs 1 set of RAW images in the working
# directory, within one directory: lights/
#
############################################

requires 1.2.4

# Convert Light Frames to .fit files
cd lights
convert light -fitseq -out=../process
cd ../process

# Calibrate Light Frames
calibrate light -cfa -equalize_cfa

# Extract Ha and OIII
seqextract_HaOIII pp_light

# Align Ha lights
setref Ha_pp_light 1
register Ha_pp_light -drizzle
seqapplyreg Ha_pp_light -drizzle -framing=max -filter-round=2.5k

# Stack calibrated Ha lights to Ha_stack (temporary)
stack r_Ha_pp_light rej 3 3 -norm=addscale -output_norm -out=results_00001

# and flip if required
mirrorx_single results_00001

# Align OIII lights
setref OIII_pp_light 1
register OIII_pp_light
seqapplyreg OIII_pp_light -framing=max -filter-round=2.5k

# Stack calibrated OIII lights to OIII_stack (temporary)
stack r_OIII_pp_light rej 3 3 -norm=addscale -output_norm -out=results_00002

# and flip if required
mirrorx_single results_00002

# Align the result images, small shifts and chromatic aberrations can occur
register results
seqapplyreg results -framing=max -filter-round=2.5k

# Renorm OIII to Ha using PixelMath
pm $r_results_00002$*mad($r_results_00001$)/mad($r_results_00002$)-mad($r_results_00001$)/mad($r_results_00002$)*median($r_results_00002$)+median($r_results_00001$)
save $result_OIII$

# Save Ha final result
load r_results_00001
save $result_Ha$

# Remove stars from Ha
load result_Ha
starnet -stretch

# Remove stars from OIII
load result_OIII
starnet -stretch

# Extract R channel from starless images
pm "1.5*$starless_result_Ha$ - 0.90*$starless_result_OIII$"
save $starless_R$

# Extract G channel from starless images
pm "0.5*$starless_result_Ha$ + 0.3*$starless_result_OIII$"
save $starless_G$

# Extract B channel from starless images
pm "0.90*$starless_result_OIII$"
save $starless_B$

# Composite starless image HOO from RGB channels
rgbcomp starless_R starless_G starless_B -out=result_starless_HOO

# Extract R channel from starmask images
pm "0.8*$starmask_result_Ha$ + 0.2*$starmask_result_OIII$"
save $starmask_R$

# Extract G channel from starmask images
pm "0.8*$starmask_result_Ha$ + 0.2*$starmask_result_OIII$"
save $starmask_G$

# Extract B channel from starmask images
pm "0.8*$starmask_result_Ha$ + 0.2*$starmask_result_OIII$"
save $starmask_B$

# Composite starmask image HOO from RGB channels
rgbcomp starmask_R starmask_G starmask_B -out=result_starmask_HOO

# Recomposite stars
pm "$result_starless_HOO$ + $result_starmask_HOO$"

# Save and open finally image
save ../$result_mosaic_hoo$
load ../result_mosaic_hoo

# Tweaks - remove green noise
rmgreen

# Tweaks - Make photometric calibration
pcc